macroScript AnimViz category:"Piranha-Bytes" buttonText:"AnimViz" toolTip:"AnimViz"
(

	rollout ro_AnimViz_Main "pb AnimViz"
	(		
		button ui_Start "Visualize" pos:[5,5] width:50 height:20 tooltip:"Start!"
		button ui_DelViz "Delete" pos:[55,5] width:50 height:20 tooltip:"Delete Visualization"
 
		spinner ui_Steps "Timestep (f): " pos:[5,30] fieldwidth:30 range:[1,99999,5] scale:1 type:#integer

		radioButtons ui_Solid pos:[5,55] labels:#("Solid", "XRay") columns:2 default:2

		local vizObj
		local vizList = #()
		
		function deleteViz =
		(
			if vizList != undefined do
			(
				for o=1 to vizList.count do
				(
					if ((vizList[o] != undefined) and ((vizList[o].isDeleted) == false)) then delete vizList[o]
				)
				vizList = #()
			)
		)
		
		on ui_SelectObj picked obj do
		(
			ui_SelectObj.caption = obj.name
			vizObj = obj
			deleteViz()
		)
		
		on ui_start pressed do
		(
			vizObj = getCurrentSelection()
			
			if vizObj != undefined then
			(
				deleteViz()
				vizList = #()
				
				oldTime = sliderTime
				for f=0 to animationRange.end by ui_Steps.value do
				(
					for v=1 to vizObj.Count do
					(
						sliderTime = f
						oldParent = vizObj[v].parent
						VizObj[v].parent = undefined
	
						newViz = snapshot vizObj[v]
						newViz.name = vizObj[v].name + "_Viz_" + (f as string)
						newViz.showFrozenInGray = false
						if ui_Solid.state == 2 then newViz.XRay = true
						newViz.wireColor = VizObj[v].wirecolor
						newViz.isFrozen = true
						newViz.parent = undefined
						append vizList newViz
	
						vizObj[v].parent = oldParent
					)
				)
				sliderTime = oldTime
			)
			else messageBox "No objects selected!" title:"Error!"
		)
		
		on ui_DelViz pressed do deleteViz()
				
		on ro_AnimViz_Main close do
		(
			deleteViz()
			gc()
		)
	)
	
	createDialog ro_AnimViz_Main width:110
)