macroScript DeselectInvisibleEdges category:"Tools" tooltip:"Deselect Invisible Edges" 
(
------------------------------------
--Deselect Invisible Edges MacroScript
--Version 1.0 - 6/17/99
--Code by Borislav Petrov
--bobo@email.archlab.tuwien.ac.at
--Idea by Daniel Manahan 
------------------------------------


work_node = $
if SubObjectLevel ==2 then
(
w_node_type = modPanel.getCurrentObject ()
try
(
w_node_mod = modPanel.getModifierIndex work_node w_node_type
)
catch
(
w_node_mod = undefined
)


if w_node_mod == undefined then
	(
	edge_sel_array = getedgeselection work_node
	)
	else
	(
	edge_sel_array = getedgeselection work_node w_node_mod
	)


new_edge_selection = #()
for i in edge_sel_array do
	(
	edge_index_calc = (i/3.0)-(i/3)
	edge_index = 1
	if edge_index_calc > 0.6 then edge_index = 2
	if edge_index_calc == 0 then edge_index = 3
	
	if (getedgevis work_node (ceil(i/3.0)) edge_index)== true then 
		(
		append new_edge_selection i
		)
	)

if w_node_mod == undefined then
	(
	setedgeselection work_node new_edge_selection	
	)
	else
	(
	setedgeselection work_node w_node_mod new_edge_selection
	update work_node	
	)	
)--end if

)--end script