macroscript SetDefaultMat category:"Bobo_s Tools"
(

-------------------------------------------------------------------------------
--   File:			SetDefaultMaterials01_m032.ms
--	 Version:		v011.M032
--	 Started:       08/16/00
--	 Last Modified: 08/16/00
--   Description:	Set MEdit Slot #1 as default MAX Material. 
--	 Code by:		Borislav Petrov [Boboland]		bobo@email.archlab.tuwien.ac.at
-------------------------------------------------------------------------------
-- NOTE: An incremental Backup copy of your MEDIT.MAT library will be created 
-- before changing it.
-------------------------------------------------------------------------------

	max mtledit
	q = querybox "This operation will take the material from MEdit Slot #1\nand make it the default MEdit Material!\nDo you want to continue?" title:"SetDefaultMat"
	if q then
	(
		loadMaterialLibrary ((getDir #matlib)+"\\medit.mat")
		new_mat = meditmaterials[1]
		for i = 1 to 24 do 
		(
			if i < 10 then prefix = "0" else prefix = ""
			new_mat.name = prefix + (i as string + " - Default")
			currentMaterialLibrary[i] = copy new_mat
		)--end i loop
		num_files = getfiles ((getDir #matlib)+"\\meditbackup_*.mat")
		copyfile ((getDir #matlib)+"\\medit.mat") ((getDir #matlib)+"\\meditbackup_"+ (num_files.count + 1) as string +".mat")
		saveMaterialLibrary ((getDir #matlib)+"\\medit.mat")
		loadMaterialLibrary ((getDir #matlib)+"\\3dsmax.mat")
	)--end if q	
)--end script


macroscript MEditDefaults category:"Bobo_s Tools"
(
-------------------------------------------------------------------------------
--   File:			SetDefaultMaterials01_m032.ms
--	 Version:		v01.M032
--	 Started:       08/16/00
--	 Last Modified: 08/16/00
--   Description:	Reset all slots to defaults from MEDIT.MAT
--	 Code by:		Borislav Petrov [Boboland]		bobo@email.archlab.tuwien.ac.at
-------------------------------------------------------------------------------

	max mtledit
	q = querybox "This operation will RESET ALL material slots to defaults!\nDo you want to continue?" title:"MEditDefaults"
	if q then
	(
		loadMaterialLibrary ((getDir #matlib)+"\\medit.mat")
		for i = 1 to 24 do 
		(
		meditmaterials[i] = currentMaterialLibrary[i]
		)--end i loop
		loadMaterialLibrary ((getDir #matlib)+"\\3dsmax.mat")
	)--end if q
)--end script