------------------------------------------------------------------------------
-- MatchTransform.ms
-- By Sergo Pogosyan (www.sergepogosyan.com, contact@sergepogosyan.com)
-- Created On: 2011-03-24
-- Modified On: 
-- tested using Max 2011
-------------------------------------------------------------------------------
-- Description:
-- script matches the object offset transforms of selected object to the ones of picked object
-- after that process you can get UVW mapping from the source object and paste it to the target
-- and mapping will match
-------------------------------------------------------------------------------
-- Installing and usage:
-------------------------------------------------------------------------------
macroScript MatchTransform
	category:"Sergo Pogosyan"
	toolTip:"MatchTransform"
	buttonText:"MatchTransform"
(
	undo "Match Transform Script" on
	(
		local target_obj = selection[1]
		local source_obj = pickobject message:"Pick source object"
		local xform_mod = Xform name:"Xform (Match Transform)"
		--remember target location
		local target_pos = target_obj.objecttransform

		--align target with source (target.transform = source.transform)
		--make offsetpos the same (target.objectOffsetPos = source.objectOffsetPos)
		target_obj.objectoffsetpos = source_obj.objectoffsetpos
		target_obj.objectoffsetrot = source_obj.objectoffsetrot
		target_obj.transform = source_obj.transform

		local current_offset_matrix = (target_obj.objecttransform * inverse target_obj.transform)
		
		--move it to the target location(how?)
		xform_mod.gizmo.transform = (target_pos * inverse target_obj.transform) * inverse current_offset_matrix
		--assign xform modifier
		addModifier target_obj xform_mod
	)
)