-- Scene Notes Helper v.1 [2010-11-13] by Anubis [project3d.narod.ru]
-- Install: put the script in stdplugs\stdscripts folder
plugin Helper SceneNotes
	name:"SceneNotes"
	classID:#(0x17ccec39, 0x57492a70)
	category:"Standard"
	extends:Dummy
(
	local meshObj
	parameters pblock rollout:params
	(
		Note type:#string ui:Note_et
		from_ type:#string ui:from_et
		to_ type:#string ui:To_et
		subject_ type:#string ui:subject_et
		data_ type:#string ui:Date_et
		ShowOnLoad type:#boolean default:false ui:PopUp_cb
	)
	rollout params "Parameters"
	(
		Edittext from_et "From:    "
		Edittext To_et "To:        "
		Edittext subject_et "Subject:"
		Edittext Date_et "Date:    "
		edittext Note_et width:140 height:260 align:#right
		checkbox PopUp_cb "Show On Load"
		on params open do if from_et.text == "" do
		(
			if from_ == undefined do from_ = sysInfo.username;
			if data_ == undefined do data_ = (filterString localTime " ")[1]
		)
	)
	on getDisplayMesh do
	(
		if meshObj == undefined do meshObj = createInstance Plane length:10 width:10 lengthsegs:1 widthsegs:1 mapCoords:false
		meshObj.mesh
	)
	on attachedToNode node do (node.wirecolor = red;)
	tool create (on mousePoint click do (nodeTM.translation = gridPoint; #stop;))
	on postLoad do if ShowOnLoad and this.Note != undefined do createdialog params
)
/*
Tips & Tricks
---------------

-- get all SceneNotes instances:
	allNotes = getClassInstances SceneNotes
-- print all their comments:
	for n in allNotes where n.Comments != undefined do print n.Comments
-- use formating:
	for n in allNotes where n.Comments != undefined do (
		format "----------------------\n"
		format "-- [ % ] --\n\n" (refs.dependentNodes n firstOnly:on).name
		format "%\n\n" n.Comments
	)
-- format to the Listener only active SceneNotes:
	for n in allNotes where n.Comments != undefined \
		and n.ShowOnLoad == true do (
		format "----------------------\n"
		format "-- [ % ] --\n\n" (refs.dependentNodes n firstOnly:on).name
		format "%\n\n" n.Comments
	)

*/