Multi/Sub Object Material Creator

try(destroyDialog roll_MSOP)catch()
 
	rollout roll_MSOP "Multi/Sub-Object Presets V1.1" width:350 height:496
	(
		group "Create In Active Material Slot:"
		(
			button btn_MSStandard "Standard Multi/Sub" tooltip:"Create Standard Multi/Sub Material" width:100 height:20 align:#left across:2
			spinner spn_stdnum_mtl "Count:" tooltip:"Number of Multi/Sub Materials" width:50 height:16 range:[2,100,10] type:#integer fieldwidth:35 align:#right
 
			button btn_MSVRay "VRay Multi/Sub" tooltip:"Create VRay Multi/Sub Material" width:100 height:20 align:#left across:2
			spinner spn_vraynum_mtl "Count:" tooltip:"Number of Multi/Sub Materials" width:50 height:16 range:[2,100,10] type:#integer fieldwidth:35 align:#right
 
			button btn_MSmentalRay "MRay Multi/Sub" tooltip:"Create MentalRay Multi/Sub Material" width:100 height:20 align:#left across:2
			spinner spn_mraynum_mtl "Count:" tooltip:"Number of Multi/Sub Materials" width:50 height:16 range:[2,100,10] type:#integer fieldwidth:35 align:#right
 
			editText basename "Material Base Name: " width:190 height:16 text:"myMaterial"
		)
 
		HyperLink Hypl_homepage "..:: HYPERLINKME::.." address:"http://www.google.com/" color:(color 255 255 255) hovercolor:(color 111 111 111) visitedcolor:(color 255 255 255) align:#center
 
 
		on btn_MSStandard pressed do
		(
			mat = multimaterial()
			mat.count = spn_stdnum_mtl.value
 
			for i=1 to mat.count do
				mat[i] = standardmaterial name:(basename.text + i as String) diffusecolor:(random black white)
 
			meditmaterials[activeMeditSlot] = mat
		)--end on
 
		on btn_MSVRay pressed do
		(
			mat = multimaterial()
			mat.count = spn_vraynum_mtl.value
 
			for i=1 to mat.count do
				mat[i] = Vraymtl name:(basename.text + i as String) diffuse:(random black white)
 
			meditmaterials[activeMeditSlot] = mat
		)--end on
 
 
		on btn_MSmentalRay pressed do
		(
			mat = multimaterial()
			mat.count = spn_mraynum_mtl.value
 
			for i=1 to mat.count do
				mat[i] = Arch___Design__mi name:(basename.text + i as String) diffuse:(random black white)
 
			meditmaterials[activeMeditSlot] = mat
		)--end on
 
	)--end ro
 
 
	createDialog roll_MSOP 210 145