Rename Object to Group name

Submitted by asymptote on Mon, 2015-03-23 13:06

I have a scene with with 1,400 single objects each within it's own group. the objects are named object001. 002,003 etc etc, and the group has the name I want the object to be.
Is this possible via maxscript ?

tia

General Scripting

Comments

Submitted by ratatouille on Sun, 2020-03-08 03:01.

Heroes are there

But you still can use "interactive renamer" from here in scriptspot.

Submitted by crystal3d on Sun, 2020-02-23 14:18.

works on the whole scene

happy that i tested on a test scene,

can we get one that works on the selected group only?
and without numbers?

Submitted by barigazy on Tue, 2015-03-24 04:30.

...

Or if you not like random unique name numbering then use this fn

fn renameGroupMembers groupNode &hendles sufix =
(
	if findItem hendles (hnd = (getHandleByAnim groupNode)) == 0 do
	(
		name = groupNode.name ; number = 0 ; append hendles hnd
		groupNode = getAllGroupMembers groupNode
		groupNode = for o in groupNode collect
		(
			if isgrouphead o then o else
			(
				o.name = name+sufix
				o.name += (formattedPrint (number += 1) format:"0.3d")
				dontcollect
			)
		)
		if groupNode.count > 0 do for g in groupNode do renameGroupMembers g &hendles sufix
	)
)

bga

Submitted by pixamoon on Tue, 2015-03-24 06:29.

`

ha ! Thank you :)

Submitted by barigazy on Tue, 2015-03-24 06:39.

o_O

Now you see what I talking about :)
Group topics are interesting and mind blowing in the same time :)

bga

Submitted by pixamoon on Tue, 2015-03-24 07:24.

~

true true, thanks you for great examples to learn :)

Submitted by barigazy on Tue, 2015-03-24 04:16.

...

Here is the solution.After you run this open Schematic View to see result

hendles = #()
groups = for g in objects where isGroupHead g collect g
fn isGroupHeadMember head node act:off = 
(
	while isvalidnode node and isgroupmember node and not (act = (node.parent == head)) do node = node.parent
	act
)
fn getAllGroupMembers head = if isgrouphead head do
(
	for node in (join #() head) where isGroupHeadMember head node collect node
)
fn renameGroupMembers groupNode &hendles sufix =
(
	if findItem hendles (hnd = (getHandleByAnim groupNode)) == 0 do
	(
		name = groupNode.name
		append hendles hnd
		groupNode = getAllGroupMembers groupNode
		groupNode = for o in groupNode collect
		(
			if isgrouphead o then o else
			(
				o.name = uniquename (name+sufix) ; dontcollect
			)
		)
		if groupNode.count > 0 do for g in groupNode do renameGroupMembers g &hendles sufix
	)
)
for g in groups do (renameGroupMembers g &hendles "_Object")
free groups ; free handles

bga

Submitted by pixamoon on Mon, 2015-03-23 14:42.

`

This should make a job. Take a look.

for g in objects where isGroupHead g do (
	i = 1 
	for o in g where o != g do (
		no = case of (
			(i < 10):("00" + i as string)
			(i <100):("0" + i as string)
			default:(i as string)
		)
		o.name = g.name + no
		print o.name
		i += 1
	)
)

Best,
Pixamoon

Attachment	Size
rename_object_to_group_name.ms	254 bytes

Submitted by barigazy on Mon, 2015-03-23 16:01.

...

The question is more complex if U need to consider group inside group.
Take look this thread where I and DenisT "wage a war" about groups. :)
http://forums.cgsociety.org/showthread.php?f=98&t=1224794
Also to get "no" variable in your for loop try eazy way

no = formattedPrint i format:"0.3d"

bga

Submitted by pixamoon on Mon, 2015-03-23 17:03.

`

Thank you !
Still so much to learn :)

And yes, of course to groups inside groups... but it is just simple renaming tool base on group names

simplified code :

for g in objects where isGroupHead g do (
	i = 1 
	for o in g where o != g do (
		o.name = g.name + (formattedPrint i format:"0.3d")
		i += 1
	)
)

About this site

Rename Object to Group name

Comments

Comment viewing options

Heroes are there

works on the whole scene

...

`

o_O

~

...

`

...

`

Comment viewing options