From\To selected objects - Get\Assign material

Submitted by 1rv on Tue, 2023-01-31 06:59

The subject must work with Slate editor via shortcut.
Could anybody help please?

Scripts Wanted

Comments

Submitted by 1rv on Tue, 2023-01-31 07:50.

No, setting up shortcuts to

No, setting up shortcuts to "Assign Mat to Selection (SME)" and "pick mat from object" (ME) do nothing on my end at least.
The only thing that works for me is "Get material" form K-studio but it doesn't work with SME's main window

Submitted by jahman on Tue, 2023-01-31 09:12.

Keyboard Shortcut Override

Keyboard Shortcut Override Toggle

Submitted by 1rv on Tue, 2023-01-31 15:12.

try yourself- pick pick

from my experience pick pick material via shortcut with\without toggle override does nothing. "assign material" kinda works, but second shortcut (to turn keyboard toggle ON) needed to which is dumb

Submitted by jahman on Tue, 2023-01-31 23:03.

.

from my experience pick pick material via shortcut with\without toggle override does nothing
SME window must be in focus/active (being open isn't enough) in order for any action to work via shortcut.
Shortcuts are binded to a certain context and if the window isnt active they of course wont work...

Submitted by 1rv on Wed, 2023-02-01 03:05.

Try to assign some shortcut

Try to assign some shortcut to "pick material from selection" (say Alt+U) and see *yourself* - it does nothing in SME. No matter where's the focus SME main window\sample slots\viewport keyboard toggle on\off

Submitted by jahman on Wed, 2023-02-01 06:11.

.

I have 'Get from Selected' & 'Assign material to selection' in SME. Both working.
But there's no 'pick material from selection', basic material editor has 'Pick material from Object'. Guess you're talking about this one? Yes, can confirm that it doesn't work, niether by shortcut nor by calling actionMan.executeAction 2 "1101" directly

macroScript PickMtlFromObj
category:"Medit_Custom"
tooltip:"Pick material from object"
(
	/*
	-- #1 custom solution
	fn HasMtl n = n.material != undefined
 
	local obj = pickObject filter:HasMtl
	if isValidNode obj and obj.material != undefined do
	(
		medit.PutMtlToMtlEditor obj.material (medit.GetActiveMtlSlot())
	)
	*/
 
	-- #2 press button programmatically
	if MatEditor.isOpen() do 
  (
	local hwnd = for w in uiaccessor.getpopupdialogs() where filenameFromPath (UIAccessor.GetWindowDllFileName w) == "res1.dll" collect w
	if hwnd.count > 0 do
	(	
		hwnd = hwnd[1]
		done = false
 
		for w in windows.getChildrenHWND hwnd while not done where w[4] == "CustButton" and UIAccessor.GetWindowResourceID w[1] == 1101 do
		(
			done = true
			UIAccessor.PressButton w[1]		
		)
	)
  )
 
)

I'm pretty sure there're tons of script similar to this one already written and posted here on scriptspot. I'd choose one which works for both sme and basic mtledit

upd
and of course, when the workaround is found the correct solution comes

(
    MatEditor.open() -- force basic medit in to focus, otherwise it won't work
    actionMan.executeAction 2 "1101"
)

Submitted by 1rv on Thu, 2023-02-02 02:33.

Well "Get from Selected" is

Well "Get from Selected" is something in the right direction - thank you. Though the demand to stay focused on SME is not so user friendly, I need something working from the viewport.
Forgive my ignorance, but what am I supposed to do with the code in "upd" part?

>>I'm pretty sure there're tons of script similar to this one already written and posted here on scriptspot. I'd choose one which works for both sme and basic mtledit

I haven't found one, hence I posted here.

Submitted by jahman on Thu, 2023-02-02 05:17.

.

well, here's a quick 'pick mtl from scene for basic&sme'. not tested

macroScript PickMaterialFromScene
category:"Jahman"
tooltip:"Pick material from scene"
(
	if MatEditor.mode == #basic then
	(	
		MatEditor.open() -- force basic medit in to focus, otherwise it won't work
		actionMan.executeAction 2 "1101"
	)
	else
	(
		if not SME.IsOpen() do SME.Open()
 
		fn GetSMEWindowHandle = 
		(	
			max_hwnd = windows.getMAXHWND()
			for m in windows.getChildrenHWND 0 where m[4] == "NodeJoeMainWindow" and m[6] == max_hwnd do exit with m[1]		
		)
 
		local sme_hwnd = GetSMEWindowHandle()
 
		windows.sendMessage sme_hwnd 0x111 41005 0
 
	)
)

Submitted by 1rv on Thu, 2023-02-02 10:50.

Amazing, thanks a ton Jahman

Amazing, thanks a ton Jahman :) works so far so good
Is the eyedropper click inevitable? Can't the material be sent straight to SME?

Submitted by jahman on Thu, 2023-02-02 11:15.

.

Is the eyedropper click inevitable? Can't the material be sent straight to SME?

That's even simpler. The only difference with the original sme action that this one doesn't require sme to be focused. And keep in mind that it gets all materials from selected nodes

macroScript SmePickMaterialFromSelection
category:"Jahman"
tooltip:"SME get material from selection"
(
	if SME.IsOpen() do
	(
		(SME.GetMainframe()).setfocus()
		if SME.GetNumViews() == 0 do SME.CreateView "View1"
		actionMan.executeAction 369891408 "55581" -- Get from Selected
	)	
)

About this site