Script to place a selected object multiple times

rollout csvCloner "csvCloner" width:180 height:250 (
 
	local origObj										
 
	local clones = #()
	local matrix = #()
 
	local fileName
 
 
	pickbutton chooseObjBtn "Pick Object" width:140 tooltip:"pick the object to be cloned"
 
	button matrixImportBtn "Load Matrix" width:140 tooltip:"load the clone matrix"
 
	label lab010 ""
	button createClonesBtn "Create Clones" width:140 tooltip:"create the clones"
	button undoBtn "Delete Clones" width:140 tooltip:"delete clones" enabled:false
 
	label lab020 ""
	label lab030 ""
	button scaleUpBtn "Scale Clones Up" width:100 tooltip:"scale up clones"
	button scaleDownBtn "Scale Clones Down" width:100 tooltip:"scale down clones"
 
 
	label lab40 ""
	label lab50 "beta version" align:#right
 
 
	fn parseFile = (
 
		fileName = getOpenFileName types:"CSV Files (*.csv)|*.csv|Text File (*.txt)|*.txt|All Files (*.*)|*.*|"
 
		if fileName != undefined AND doesFileExist fileName do (
 
			matrix = #()
 
			local File = openfile fileName mode:"rt"
 
 
			while (not eof File) do (
 
 
				local LineData = readLine File
				filterString LineData ";"
 
				append matrix LineData
 
 
			)
			close File
 
		 )
 
	) -- end fn
 
 
	fn createClones = (
 
 
 
			for c=1 to clones.count do (
				delete clones[c]
			)
 
			clones = #()
 
			for i=1 to matrix.count do (
 
				newClone = instance origObj 
				tmpBlocks = filterString matrix[i] ";"
 
 
				tmpScale = tmpBlocks[1]
				tmpPos = filterString tmpBlocks[2] ","
				tmpColor = filterString tmpBlocks[3] ","
				newClone.pos = [tmpPos[1] as float,tmpPos[2] as float,origObj.pos[3]]
 
 
				tmpScaleValue = tmpBlocks[1] as float/100
 
				scale newClone [tmpScaleValue,tmpScaleValue,tmpScaleValue]
 
 
 
 
 
				-- make materials:
				baseMat = getMeditMaterial 1
 
				newMat = copy baseMat
				newMat.name = baseMat.name+"_"+ i as string
				newMat.diffuse = (color (tmpColor[1] as float) (tmpColor[2] as float) (tmpColor[3] as float))
 
				newClone.material = newMat
 
				append clones newClone
			)
 
 
		undoBtn.enabled = true
 
 
 
	)
 
 
 
 
	fn scaleClones scaleDir = (
 
		if scaleDir == "upDir" do (
			scaleSize = [1.1,1.1,1.1]
		) -- end if
 
		if scaleDir == "downDir" do(
			scaleSize = [0.9,0.9,0.9]
		) -- end if
 
 
		if (clones.count >=1) do (
 
			for c=1 to clones.count do (
				scale clones[c] scaleSize
			)
 
		)
 
	) -- end fn
 
 
 
 
 
 
 
 
 
 
 
	on createClonesBtn pressed do (
 
		if ( (origObj == undefined) or (fileName == undefined) ) then (
 
			messageBox "please pick the object to be cloned and also load your csv-file before creating clones"
 
		) else (
 
			createClones()
 
		)
 
 
	) -- end on
 
 
	on matrixImportBtn pressed do (
 
		parseFile()
 
	) -- end on
 
 
	on chooseObjBtn picked obj do( 
 
		if obj != undefined do(
 
			obj.wirecolor = red
			origObj = obj
 
			chooseObjBtn.text = obj.name
 
			origObjScale = origObj.scale
 
		) --end if
	) --end on
 
 
	on undoBtn pressed do(
 
			for c=1 to clones.count do (
				delete clones[c]
			)
 
			clones = #()
 
			undoBtn.enabled = false
	) -- end on
 
 
	on scaleUpBtn pressed do (
		scaleDir = "upDir"
		scaleClones scaleDir
	) -- end on
 
	on scaleDownBtn pressed do (
		scaleDir = "downDir"
		scaleClones scaleDir
	) -- end on
 
)
 
createdialog csvCloner
 
-- script by le1setreter