Switching object properties>renderable on and off from attribute holder

By savascetin · 2012-09-14

Description

Hi
I want to switch objects renderable property on and off from attribute holder.
I can switch off renderable property by maxscript by "$.renderable = off". how can I connect this property to attribute holder.
Thank you

Comments (4)

Thanks

savascetin · 2012-09-17

Thank you again

try this

barigazy · 2012-09-14

rendOnOffCA = attributes rendOnOff
(
parameters main rollout:roll
(
rend_on_off type:#boolean animatable:false ui:cb_on_off default:on

)
rollout roll "Parameters"
(
checkbox cb_on_off "Renderable"
on cb_on_off changed state do ((refs.dependentNodes (custAttributes.getOwner this))[1]).renderable = state
)
)
emptyMod = EmptyModifier name:"Render Switcher"
obj = Box()
custAttributes.add emptyMod rendOnOffCA
addmodifier obj emptyMod

savascetin · 2012-09-14

Thank you. How can i use this script on a precreated object?

barigazy · 2012-09-14

This is better solution using function.
Just select object and run code below

fn addRenderSwitcher obj =
(
rendOnOffCA = attributes rendOnOff
(
parameters main rollout:roll
(
rend_on_off type:#boolean animatable:false ui:cb_on_off default:on
currobj type:#maxObject

)
--this.currobj = (NodeTransformMonitor node:obj)
rollout roll "Parameters"
(
checkbox cb_on_off "Renderable"
on cb_on_off changed state do currobj.node.renderable = state
)
)

emptyMod = EmptyModifier name:"Render Switcher"
custAttributes.add emptyMod rendOnOffCA
emptyMod.currobj = nodeTransformMonitor node:obj forwardTransformChangeMsgs:false
addmodifier obj emptyMod
)
addRenderSwitcher $