Vray Setting comparing in single window

By image3d · 2018-10-06

Description

I want 2 different vray setting comparing in a single window with hi-light change in between two vray setting.

i use vray 2.4 before. that time i save my preset. now switch to new vray 3.4 but when i start render in that show white dot after changing sub pix setting clamp out then also they show white dote. lastly i use my old preset and work well on same file. so need help which setting is in old preset and new 3ds max vary setting for compare easily.

thanking you in advance

Comments (1)

pixamoon · 2018-10-24

Hi,

Here is a simple script,

1st button saves current renderer settings to global variable.
2nd button compare this settings with new loaded settings

Differences will be printed to MaxScript Listener.


(
	::tmpRSettings

	fn saveRSettings = (
		
		local rc = renderers.current
		
		str = "struct tmpStr ( " 
		
		for p in getpropnames rc do (
			str += p as string + ", "
		)
		
		str += "end ); "
		str += "::tmpRSettings = tmpStr()"
		
		execute str
		
		for p in getpropnames rc do (
			setproperty ::tmpRSettings p (getproperty rc p)
		)
	)

	fn compareRSettings = (
		
		local rc = renderers.current
		
		if superclassof ::tmpRSettings == StructDef do
			for p in getpropnames rc do 
				if getproperty rc p != getproperty ::tmpRSettings p do print (p as string + "   1: " + (getproperty rc p) as string + " 2: " + (getproperty ::tmpRSettings p) as string)
		
	)

	try(destroyDialog ::CompareRenderSettings)catch()
	rollout CompareRenderSettings "Compare Render Settings" width: 200 (
		
		button bn_SaveRS "Save Current Renderer Settings"
		button bn_CompareRS "Compare Current Renderer Settings"
		
		on bn_SaveRS pressed do saveRSettings()
		on bn_CompareRS pressed do compareRSettings()
	)

	createDialog ::CompareRenderSettings
)

Best,
Pixamoon