ClaverTech-LightCluder

macroScript LightCluder
	category:"ClaverTech"
	toolTip:"LightCluder-Quick Light Clusions"
(
	objs=#()
	Lits=#()
 
	fn g_filter o =((isKindOf o GeometryClass) And classOf o!=TargetObject) or(isKindOf o Dummy and isGroupHead o)
	fn l_filter o =isKindOf o Light
 
	rollout unnamedRollout "ClaverTech - LightCluder" width:368 height:194
(
	button btnLits "Select Lights" pos:[230,14] width:117 height:23
	listBox lbxLits "Light List" pos:[231,41] width:116 height:9
	button btnGeom "Select Geometry" pos:[20,14] width:117 height:23
	button btnGrab " $ " pos:[165,14] width:40 height:23 align:#center toolTip:"Grab Selected Nodes"
	listBox lbxGeom "Geometry List" pos:[21,41] width:116 height:9
	button btnExcluder "Exclude" pos:[150,77] width:73 height:24
	button btnIncluder "Include" pos:[150,136] width:73 height:24
 
	on btnGrab pressed do
	(
		objs=#()
		Lits=#()
		Temp=getCurrentSelection()
		print Temp
		if(Temp.count>0) then
		(
		objs=for j in Temp where ((isKindOf j GeometryClass and not isGroupMember j And classOf j!=TargetObject) or (isKindOf j Dummy and isGroupHead j)) collect j
		names=for k in objs collect k.name
		lbxGeom.items=names
 
		Temp=getCurrentSelection()
		Lits=for j in Temp where (isKindOf j Light) collect j
		names=for k in Lits collect k.name
		lbxLits.items=names
		)
		else
		(
			messageBox "Select the Objects in the scene then Click this"
		)
	)
 
	on btnGeom pressed do
	(
		Temp=selectByName  title:"Select Geometry To CLude" filter:g_filter
		print Temp
		if(Temp!=undefined)then
		(
		objs=(for j in Temp where ((isKindOf j GeometryClass And classOf j!=TargetObject) or (isKindOf j Dummy and isGroupHead j)) collect j)
		names=for k in objs collect k.name
		lbxGeom.items=names
		)
	)
	on btnLits pressed do
	(
		Temp=selectByName  title:"Select Light To CLude" filter:l_filter
		if(Temp!=undefined)then
		(
		Lits=for j in Temp where (isKindOf j Light) collect j
		names=for k in Lits collect k.name
		lbxLits.items=names
		)
	)
	on btnExcluder pressed do
	(
		for lt in Lits do
		(
			if(lt.excludeList==undefined)then(lt.excludeList=#())
			if(objs.count>0)then
			(
				lt.excludeList=join lt.excludeList objs
			)
			else
			(
				lt.excludeList=#()
			)
		)
	)
	on btnIncluder pressed do
	(
		for lt in Lits do
		(
			if(lt.includeList==undefined)then(lt.includeList=#())
			if(objs.count>0)then
			(
				lt.includeList=join lt.includeList objs
			)
			else
			(
				lt.includeList=#()
			)
		)
	)
)
 
CreateDialog unnamedRollout 368 194
)