Edit Poly vertex Collapse with Scale (Scale vertices). Thanx Miauu

Submitted by Nik on Tue, 2013-07-30 03:09

How to make as well as in this video for script?

http://youtu.be/YTGKr-CvNyQ

scale $.selectedVerts [0,0,0] does not work :(

‹ Open merge Animation dialog with maxscript Taking that next step - Mergeing files ›

Comments

Comment viewing options

Select your preferred way to display the comments and click "Save settings" to activate your changes.
miauu's picture
Submitted by miauu on Wed, 2013-07-31 05:46.

:) Glad to help. :)

:)
Glad to help.
:)

Tools and Scripts for Autodesk 3dsMax

Nik's picture
Submitted by Nik on Wed, 2013-07-31 04:37.

Just cool!

I'm happy :) Thanx

Nik's picture
Submitted by Nik on Wed, 2013-07-31 04:39.

A HUGE THANK YOU, GREAT MAN. THIS GORGEOUS

JUST WELL DONE Thank you for this work and spent time on me.

AttachmentSize
images.jpg 9.45 KB
miauu's picture
Submitted by miauu on Wed, 2013-07-31 01:05.

Send me the scene with the

Send me the scene with the teapot and I will find where the problem is.

I've also noticed that sometimes pressing the Collapse button in modify panel(executing the sctip code also) not collapse all verts(some of they stays in places).

Tools and Scripts for Autodesk 3dsMax

Nik's picture
Submitted by Nik on Wed, 2013-07-31 02:22.

here please

file attached

AttachmentSize
teapot_with_edit_poly_ver._max_2010_.max 828 KB
miauu's picture
Submitted by miauu on Wed, 2013-07-31 03:03.

.

(
	curO = modPanel.getCurrentObject()
	if classof curO == Edit_Poly do
	(
		allVertsBA = curO.GetSelection #Vertex
		if allVertsBA.numberset != 0 do
		(
			centerPos = [0,0,0]
			for v in allVertsBA do 
			(
				vPos = curO.getVertex v
				centerPos.x += vPos.x
				centerPos.y += vPos.y
				centerPos.z += vPos.z
			)
			centerPos /= allVertsBA.numberset
 
			curO.SetOperation #Transform
			curO.ScaleSelection  [1e-005,1e-005,1e-005] parent:(transMatrix centerPos) axis:(transMatrix centerPos)
			curO.Commit ()
		)
	)
	if classof curO == Editable_Poly do
	(
		local poGetVert = polyop.getVert
		local poSetVert = polyop.setVert
		allVertsBA = polyop.getVertSelection curO
		if allVertsBA.numberset != 0 do
		(
			centerPos = [0,0,0]
			for v in allVertsBA do 
			(
				vPos = poGetVert curO v
				centerPos.x += vPos.x
				centerPos.y += vPos.y
				centerPos.z += vPos.z
			)
			centerPos /= allVertsBA.numberset
			for v in allVertsBA do
			(
				poSetVert curO v centerPos
			)
		)
	)
)

Tools and Scripts for Autodesk 3dsMax

miauu's picture
Submitted by miauu on Tue, 2013-07-30 11:57.

...

With Edit Poly modifier:

$.modifiers[1].ButtonOp #CollapseVertex
$.modifiers[1].Commit()

Or if you wants to do it with the scale:

(
	allVertsBA = $.modifiers[#Edit_Poly].GetSelection #Vertex
	centerPos = [0,0,0]
	for v in allVertsBA do 
	(
		vPos = $.modifiers[#Edit_Poly].getVertex v node:$
		centerPos.x += vPos.x
		centerPos.y += vPos.y
		centerPos.z += vPos.z
	)
	centerPos /= allVertsBA.numberset
 
	$.modifiers[#Edit_Poly].SetOperation #Transform
	$.modifiers[#Edit_Poly].ScaleSelection  [1e-005,1e-005,1e-005] parent:(transMatrix centerPos) axis:(transMatrix centerPos)
	$.modifiers[#Edit_Poly].Commit ()
)

What you mean by attached object?

Tools and Scripts for Autodesk 3dsMax

Nik's picture
Submitted by Nik on Tue, 2013-07-30 21:03.

Sorry does not work

with scale:

-- Unknown property: "modifiers" in $selection

Moreover, when try to repeat the code obtained from MAXscript Listener, all turns out the same way.

And

$.modifiers[1].ButtonOp #CollapseVertex
$.modifiers[1].Commit()

not working properly too.

AttachmentSize
error.gif 102.49 KB
Nik's picture
Submitted by Nik on Tue, 2013-07-30 09:38.

Oo, thanx miauu but...

But I realized that I had to do it this way

http://youtu.be/l8-1XuedY7A

For me this for the time being difficult. Please help
And even to the same how this will be with attached objects.

Thanx for response.

miauu's picture
Submitted by miauu on Tue, 2013-07-30 05:44.

.

Try this:

polyop.collapseVerts $ (polyop.getVertSelection $)

Works only with editable poly objects

Tools and Scripts for Autodesk 3dsMax

Comment viewing options

Select your preferred way to display the comments and click "Save settings" to activate your changes.