Help with a simple renaming script

try(destroyDialog ::renameMaps)catch()
rollout renameMaps "rename Maps"
(
	local slots = #("Diffuse Map", "Specular Map", "Normal Map")
	local sufix = #("_DIFF", "_SPEC", "_NORM")
	group " _Sufix : " 
	(
		edittext et_diff "Diffuse   :" pos:[10,25] width:180 height:17 text:sufix[1]
		edittext et_spec "Specular :" pos:[10,45] width:180 height:17 text:sufix[2]
		edittext et_norm "Normal    :" pos:[10,65] width:180 height:17 text:sufix[3]
	)
	group " Add && Rename : "
	(
		dropdownlist ddl_s "Source:" pos:[8,110] width:90 height:5 items:slots
		dropdownlist ddl_t "Target:" pos:[102,110] width:90 height:5 items:(for i = 2 to 3 collect slots[i])
	)
	button btn_doit "DO THE JOB!" pos:[4,150] width:192 height:35
	on ddl_s selected idx do (ddl_t.items = for n in slots where ddl_s.selected != n collect n)
	on btn_doit pressed do
	(
		if selection.count == 0 then messageBox "Select Some Object!" title:"Warning" beep:off else
		(
			sufix = #(et_diff.text, et_spec.text, et_norm.text) ; array = #()
			for node in selection where node.mat != undefined do
			(
				if (material = getClassInstances Standardmaterial target:node).count != 0 do
				(
					for mat in material where mat.filterMapAmount != 17 do
					(
						case ddl_s.selection of
						(
							1:
							(
								if mat.diffuseMap != undefined and isKindOf mat.diffuseMap bitmapTex do
								(
									string = getFilenameFile mat.diffuseMap.filename
									mat.diffuseMap.name = string + sufix[1]
									if ddl_t.selected == slots[2] then mat.specularLevelMap = (map = copy mat.diffuseMap ; map.name = (string + sufix[2]) ; map)
									else mat.bumpMap = (map = copy mat.diffuseMap ; map.name =  (string + sufix[3]) ; map)
								)
							)
							2:
							(
								if mat.specularLevelMap != undefined and isKindOf mat.specularLevelMap bitmapTex do
								(
									string = getFilenameFile mat.specularLevelMap.filename
									mat.specularLevelMap.name = string + sufix[2]
									if ddl_t.selected == slots[1] then mat.diffuseMap = (map = copy mat.specularLevelMap ; map.name = (string + sufix[1]) ; map)
									else mat.bumpMap = (map = copy mat.specularLevelMap ; map.name = (string + sufix[3]) ; map)
								)								
							)
							3:
							(
								if mat.bumpMap != undefined and isKindOf mat.bumpMap bitmapTex do
								(
									string = getFilenameFile mat.bumpMap.filename
									mat.bumpMap.name = string + sufix[3]
									if ddl_t.selected == slots[1] then mat.diffuseMap = (map = copy mat.bumpMap ; map.name = (string + sufix[1]) ; map)
									else mat.specularLevelMap = (map = copy mat.bumpMap ; map.name = (string + sufix[2]) ; map)
								)								
							)
						)
						mat.filterMapAmount = 17
						append array mat
					)
					array.filterMapAmount = 100
				)
			)
		)
	)
)
createDialog renameMaps 200 190 style:#(#style_titlebar, #style_sysmenu, #style_toolwindow)