How do I get the progress information of the rendering?

gc light:true
try (
	::renderProgressTimer.Stop() 
	dotNet.removeAllEventHandlers ::renderProgressTimer
)catch()
 
global renderingDialogHWND = undefined
global renderProgressTimer = dotnetobject "System.Windows.Forms.Timer"
renderProgressTimer.interval = 2000 -- two seconds
 
fn onTick sender arg = 
(	
	if isKindOf ::renderingDialogHWND IntegerPtr do 
	(
		local data = windows.getHWNDData ::renderingDialogHWND
 
		if data == undefined then
		(
			format "Timer is stopping..\n" 
			sender.Stop()
 
			DialogMonitorOPS.enabled = false
			DialogMonitorOPS.UnRegisterNotification id:#renderProgress
		)
	)
 
)
dotnet.addEventHandler renderProgressTimer "Tick" onTick 
 
 
bw = dotNetObject "CSharpUtilities.SynchronizingBackgroundWorker"
fn dowork =
(
	format "Background worker started\n" 
	local t = timeStamp()
 
	while ::renderProgressTimer.enabled do
	(
		if timeStamp() - t >= ::renderProgressTimer.interval do
		(
			t = timeStamp()
 
			local data = windows.getHWNDData ::renderingDialogHWND
 
			if data != undefined do
			(				
				for c in windows.getChildrenHWND ::renderingDialogHWND where c[4] == "Static" do 
				(
					if MatchPattern c[5] pattern:"Rendering*pass*" do format "!>> %\n" c[5]			
 
				)
			)
		)
	)
 
	format "Background worker completed\n" 
 
)
dotnet.addEventHandler bw "DoWork" dowork
 
 
fn onWindow =
(
	local hwnd = DialogMonitorOPS.GetWindowHandle()
 
	if hwnd != undefined do
	(
		local data = windows.getHWNDData hwnd
 
		if data[4] == "#32770" and data[5] == "Rendering" do
		(
			format "Rendering...\n" 
			if isKindOf ::renderProgressTimer dotNetObject do 
			(
				format "Starting timer\n" 
				::renderingDialogHWND = data[1]
				::renderProgressTimer.start()
 
				::bw.runWorkerAsync()
 
			)
 
		)
 
	)
 
	true
)
 
DialogMonitorOPS.UnRegisterNotification id:#renderProgress
DialogMonitorOPS.RegisterNotification onWindow id:#renderProgress
DialogMonitorOPS.enabled = true
 
clearListener()