Move selected polys in order

(
	global rol_movePolys
	try(destroyDialog rol_movePolys)catch()
	rollout rol_movePolys "Move Polygons"
	(
		local curO = undefined
		local firstPolyBA = #{}
		local allStairsFacesBA = #{}
 
		local poGetVertsUsingFace = polyop.getVertsUsingFace
		local poGetFaceCenter = polyop.getFaceCenter
		local poGetFaceSelection = polyop.getFaceSelection
		local poMoveVert = polyop.moveVert
 
		button btn_getFirstFace "Get first face" width:140
		button btn_getAllOtherfaces "Get all faces" width:140
		spinner spn_moveVal "" range:[10,1e9,10] type:#worldUnits
		button btn_moveFaces "Move faces" width:140
 
		function SortByXMember arr1 arr2 x:1 =
		(
			case of
			(
				(arr1[x] < arr2[x]):-1
				(arr1[x] > arr2[x]):1
				default:0
			)
		)
 
		on btn_getFirstFace pressed do
		(
			if selection.count == 1 and classOf selection[1] == Editable_Poly and subobjectlevel == 4 do
			(
				curO = selection[1]
				if (firstPolyBA = poGetFaceSelection curO).numberset == 1 then
				(
 
				)
				else
				(
					messagebox "Select only one polugon" title:""
				)
			)
		)
 
		on btn_getAllOtherfaces pressed do
		(
			if (allStairsFacesBA = poGetFaceSelection curO).numberset != 0 then
			(
				allStairsFacesBA -= firstPolyBA
			)
			else
			(
				messagebox "Select stair's faces" title:""
			)
		)
 
		on btn_moveFaces pressed do
		(
			if not firstPolyBA.isEmpty and not allStairsFacesBA.isEmpty do
			(
				stairFacesArr = #()
				zeroPos = poGetFaceCenter curO (firstPolyBA as array)[1]
				for f in allStairsFacesBA do
				(
					fPos = poGetFaceCenter curO f
 
					append stairFacesArr #((distance fPos zeroPos), poGetVertsUsingFace curO f)
				)
 
				qsort stairFacesArr SortByXMember x:1
 
				zOffset = spn_moveVal.value
				for i = 1 to stairFacesArr.count do
				(
					poMoveVert curO stairFacesArr[i][2] [0,0,(zOffset * i)]
				)
			)
		)
 
	)
	createdialog rol_movePolys 	
)