points file to line, line to point file

Submitted by TomB on Tue, 2020-09-15 08:04

I'm looking for a script (or someone to create one for me) that reads a comma delimited csv file (X,Y,Z) and creates a multi-point line (close it at the last point). and another script to take a multi-point line and save it back into the same csv format.

syntax sample

1.2345, 2.3456, 3.4567

thanks...Tom

Scripts Wanted

Comments

Submitted by miauu on Fri, 2020-09-18 12:11.

.

(
	global rol_splineFromTXT
	try(destroyDialog rol_splineFromTXT)catch()
	rollout rol_splineFromTXT "miauu Spline from file"
	(
		button btn_txtToSpline "TXT to Spline" width:140
		button btn_splineToTxt "Spline to TXT"  width:140
 
		on btn_txtToSpline pressed do
		(
			txtFile = openFile (getOpenFileName())
			if txtFile != undefined do
			(
				ss = splineShape()
				addNewSpline ss
				while not eof txtFile do
				(
					fStr = filterString (readline txtFile) "," splitEmptyTokens:false
					if fStr.count == 3 do
					(
						addKnot ss 1 #smooth #curve [fStr[1] as float, fStr[2] as float, fStr[3] as float]
					)
				)
				close ss 1
				close txtFile
			)
		)
 
		on btn_splineToTxt pressed do
		(
			if selection.count == 1 and classOf selection[1] == SplineShape or classOf selection[1] == Line do
			(
				txtFile = (getSaveFileName())
				if txtFile != undefined do
				(					
					outFile = createFile (txtFile + ".txt")
					ss = selection[1]
					knotsCnt = numKnots ss 1 
					for k = 1 to knotsCnt do
					(
						kPos = getKnotPoint ss 1 k
						format "%,%,%\n" kPos.x kPos.y kPos.z to:outFile
					)
					flush outFile
					close outFile
					messagebox "Done!" title:""
				)
			)
 
		)
 
	)
	createdialog rol_splineFromTXT 
 
)

Spline primitives(Circle, Donut, Rectangle, etc.) are not supported when the splines' points are saved in a txt file.

This will convert the selected shape to editable spline(which you may not want to happen), so Circles, Rentangles, etc. are supported:

(
	global rol_splineFromTXT
	try(destroyDialog rol_splineFromTXT)catch()
	rollout rol_splineFromTXT "miauu Spline from file"
	(
		button btn_txtToSpline "TXT to Spline" width:140
		button btn_splineToTxt "Spline to TXT"  width:140
 
		on btn_txtToSpline pressed do
		(
			txtFile = openFile (getOpenFileName())
			if txtFile != undefined do
			(
				ss = splineShape()
				addNewSpline ss
				while not eof txtFile do
				(
					fStr = filterString (readline txtFile) "," splitEmptyTokens:false
					if fStr.count == 3 do
					(
						addKnot ss 1 #smooth #curve [fStr[1] as float, fStr[2] as float, fStr[3] as float]
					)
				)
				close ss 1
				close txtFile
			)
		)
 
		on btn_splineToTxt pressed do
		(
			if selection.count == 1 and superClassOf selection[1] == Shape do
			(
				txtFile = (getSaveFileName())
				if txtFile != undefined do
				(					
					outFile = createFile (txtFile + ".txt")
					ss = selection[1]
					convertToSplineShape ss
					knotsCnt = numKnots ss 1 
					for k = 1 to knotsCnt do
					(
						kPos = getKnotPoint ss 1 k
						format "%,%,%\n" kPos.x kPos.y kPos.z to:outFile
					)
					flush outFile
					close outFile
					messagebox "Done!" title:""
				)
			)
 
		)
 
	)
	createdialog rol_splineFromTXT 
 
)