regardless of edtiable poly and editable mesh , how can i clear smothing group

Submitted by dussla on Wed, 2014-07-16 08:00

if i select objects editable meshs or editable polys
i would like to clear smoothing groups

can you help me again ?
thank you always

Scripts Wanted

Comments

Submitted by barigazy on Fri, 2015-06-19 07:47.

With this fn you can clear

With this fn you can clear SG, set Mtl id to 1 and triangulate EditablePoly objects.

fn clearSmoothAndID = if selection.count > 0 do
(
	local setSG = polyop.setFaceSmoothGroup, setFID = polyop.setFaceMatID, retriangulate = polyop.retriangulate	
	for o in selection where isKindOf o Editable_Poly do
	(
		e = #{1..o.faces.count}
		setSG o e 0 ; setFID o e 1 ; retriangulate o e
	)
)

bga

Submitted by miauu on Mon, 2014-07-21 12:19.

.

Try this:

macroscript miauuClearSmoothingGroups
category:"miauu"
tooltip:"Clear SGs"
buttonText:"Clear SGs"
(
	if selection.count != 0 do
	(
		for o in selection as array do
		(
			case classOf o of
			(
				Editable_Poly:
				(
					(
						o.selectedfaces = #{1..o.numfaces}
						o.setSmoothingGroups 0 -1 1
					)
				)
				Editable_Mesh:
				(
					facesBA = #{1..o.numfaces}
					o.selectedfaces = facesBA
					for f in facesBA do
						setFaceSmoothGroup o f 0
					update o
				)
			)
		)
	)
)