How to assign hotkey for these commands? (vertices properties in spline)

Submitted by nnq2603 on Mon, 2016-12-19 21:56

These command list below in this image. Spline \ corner, bezier, smooth, etc... Haven't figure out to assign hotkey to any of them. I know rightclick menu is quite fast, but for some tasks in my current work, those command need to execute a lot of time and I prefer hotkey than context menu.

http://i.imgur.com/otfuhmL.gif

And I know how to assign hotkey/shortcut key in 3ds max for other commands. Normal way is rightclick>customize>Keyboard tab, pick the right Category (or Group), then navigate to the wanted command, assign a letter/symbol,key to it. But these vertex command such as corner, bezier... I couldn't find out in entire list of commands in 3ds max. They must be somewhere there but I can't find. Could this issue be solved with a little script or..?

General Scripting

Comments

Submitted by tahir1983 on Sat, 2018-05-26 06:03.

wonderfull! but if add undo

wonderfull! but if add undo it will be excellently!

Submitted by jahman on Sat, 2018-05-26 06:13.

.

you need to modify these macro a little for undo to work

if classOf curO == SplineShape or classOf curO == Line do
		(
			convertToSplineShape curO
			splinesCnt = numSplines curO
...
...

Submitted by miauu on Thu, 2016-12-22 12:55.

.

macroscript miauuConertSplineKnotsToSmooth
category:"miauu"
tooltip:"Convert Knots to Smooth"
buttonText:"Convert Knots to Smooth"
(
	if selection.count == 1 do
	(
		curO = selection[1]
		if classOf curO == SplineShape or classOf curO == Line do
		(
			splinesCnt = numSplines curO
			for ss = 1 to splinesCnt do
			(
				selKnotsArr = getKnotSelection curO ss
				for k in selKnotsArr do
					setKnotType curO ss k #smooth
			)
			updateShape curO
		)		
	)	
)
 
macroscript miauuConertSplineKnotsToCorner
category:"miauu"
tooltip:"Convert Knots to Corner"
buttonText:"Convert Knots to Corner"
(
	if selection.count == 1 do
	(
		curO = selection[1]
		if classOf curO == SplineShape or classOf curO == Line do
		(
			splinesCnt = numSplines curO
			for ss = 1 to splinesCnt do
			(
				selKnotsArr = getKnotSelection curO ss
				for k in selKnotsArr do
					setKnotType curO ss k #corner
			)
			updateShape curO
		)		
	)	
)
 
macroscript miauuConertSplineKnotsToBezier
category:"miauu"
tooltip:"Convert Knots to Bezier"
buttonText:"Convert Knots to Bezier"
(
	if selection.count == 1 do
	(
		curO = selection[1]
		if classOf curO == SplineShape or classOf curO == Line do
		(
			splinesCnt = numSplines curO
			for ss = 1 to splinesCnt do
			(
				selKnotsArr = getKnotSelection curO ss
				for k in selKnotsArr do
					setKnotType curO ss k #bezier
			)
			updateShape curO
		)		
	)	
)
 
macroscript miauuConertSplineKnotsToBezierCorner
category:"miauu"
tooltip:"Convert Knots to BezierCorner"
buttonText:"Convert Knots to BezierCorner"
(
	if selection.count == 1 do
	(
		curO = selection[1]
		if classOf curO == SplineShape or classOf curO == Line do
		(
			splinesCnt = numSplines curO
			for ss = 1 to splinesCnt do
			(
				selKnotsArr = getKnotSelection curO ss
				for k in selKnotsArr do
					setKnotType curO ss k #bezierCorner
			)
			updateShape curO
		)		
	)	
)

If you don't like the category or the names/tooltips of the macros - change them.

Tools and Scripts for Autodesk 3dsMax

Submitted by nnq2603 on Mon, 2016-12-26 03:03.

Return some errors.

I get this error:

---------------------------
MAXScript MacroScript Error Exception
---------------------------
-- Runtime error: Spline operation on non-spline: Rectangle
---------------------------
OK   
---------------------------

Edit Spline modifier above Rectangle. How to add Edit Spline object to script? (beside spline and line)

Submitted by miauu on Mon, 2016-12-26 13:18.

.

I can't find how to add support for Editable Spline modifier.

Tools and Scripts for Autodesk 3dsMax

Submitted by nnq2603 on Thu, 2016-12-22 20:14.

Thanks for detailed answer.

Thanks a lot, miauu. I'll use it and get back later if there's any problem (probably there's not).

About this site