ScriptSpot

Forum topic · Scripts Wanted

resize output size for preview rendering

By themaxxer · 2018-06-20

Description

hi all

I can't script at all, so I ask here, maybe someone could make this...

I would like to have a little script in which you can switch between several output sizes for render sizes.

for example you have set the final output size at 2060x1440 for a quick preview you want to set it two 1/2 or 1/4 size of it. now you have to set the size in the render setup and it is very complicated and slow.

I would appreciate a little script like this.

thanks to all scripters out there

best regards
themaxxer

Comments (3)

themaxxer · 2018-06-21

wow, thank you so much!! this is so handy...
I have several scripts from you. :)
gamma organizer, material ID organizer and merge and relink

very useful tolls, thanks for your effort.

best regards
themaxxer

`

pixamoon · 2018-06-21

cool, no prob,

Happy it helped :)
Pixamoon

`

pixamoon · 2018-06-21

Hey,

Here is simple rollout with 2 buttons: 1/2 and 1/4

They will resize and start render - and set original size after render,

Here is a code and you can find bellow link to download ms file.

ms file can be drag ad dropped to max viewport or used with Favorite Scripts:
www.scriptspot.com/3ds-max/scripts/favorite-scripts 


(
	try(destroyDialog ::renderReSize)catch()
	
	rollout renderReSize "" (
		
		local me = renderReSize
		local orgRes = #(RenderWidth, RenderHeight)
		
		label lb_orgSize "" align:#center
		button bn_12 "1 / 2" width:(me.width - 8)
		button bn_14 "1 / 4" width:(me.width - 8)
		
		timer rendSettCheck interval:1000 active:true
		
		fn quickRender d = (
			rendSettCheck.active = false
			
			RenderWidth = RenderWidth / d
			RenderHeight = RenderHeight / d
			renderSceneDialog.update()
			
			max Quick Render
			
			RenderWidth = orgRes[1]
			RenderHeight = orgRes[2]
			renderSceneDialog.update()
			
			rendSettCheck.active = true
		)

		on renderReSize open do rendSettCheck.tick()
		
		on rendSettCheck tick do (
			rendSettCheck.active = false
			
			orgRes = #(RenderWidth, RenderHeight)
			local txt = RenderWidth as string + " x " + RenderHeight as string
			if txt != lb_orgSize.text do lb_orgSize.text = txt
			
			rendSettCheck.active = true
		)
		
		on bn_12 pressed do quickRender 2
		on bn_14 pressed do quickRender 4
		
	)
	
	createDialog renderReSize
	
	ok
)

Best,
Pixamoon

Attachments