Bbox Border plane and attach all mesh

(
	fn planesOverFaces obj orient = 
	(	
		local planeArr = #()
		local ev = polyop.getEdgeVerts
		local gv = polyop.getvert
		local gfe = polyop.getFaceEdges
		local gfsc = polyop.getSafeFaceCenter
		local gfn = polyop.getFaceNormal
		local allFaces = (obj.Faces as bitarray) as array
		for f in allFaces do
		(
			getEdges = gfe obj f
			local sizeArr = #()
			for i in getEdges do
			(
				append sizeArr (distance (gv obj (ev obj i)[2]) (gv obj (ev obj i)[1]))
			)
			if orient == 0 then
			(w = amin sizeArr ; l = amax sizeArr)
			else
			(l = amin sizeArr ; w = amax sizeArr)
			fc = gfsc obj f
			nf = gfn obj f
			xv = normalize (cross nf [0,0,1])
			yv = normalize (cross nf xv)
			thePlane = plane length:l width:w lengthsegs:1 widthsegs:1 name:(uniquename "FacePlane")\
			isSelected:on wirecolor:(random black white) transform:(matrix3 xv yv nf fc)
			append planeArr thePlane
		)
		select planeArr
	)
 
	fn createBoxAsCage obj = if isValidNode obj do
	(
		local bb = in coordsys local nodeLocalBoundingBox obj
		local wX = abs((bb[1]-bb[2]).x) , lY = abs((bb[1]-bb[2]).y) , hZ = abs((bb[1]-bb[2]).z)
		local cage = convertToPoly (box width:wX length:lY height:hZ mapcoords:on name:"Cage" wirecolor:black)
		CenterPivot cage
		local tm = obj.transform
		tm.row4 = obj.center
		cage.transform = tm
		polyop.deleteFaces cage #{1,2}
		planesOverFaces cage (if wX < hZ then 0 else 1)
                delete cage
	)
	createBoxAsCage selection[1]
)