mapDroper

/*//////////   SCRIPT:   mapDroper v.1.0   //////////*/
/*//////////   WRITTEN BY:   Branko Zivkovic   //////////*/
/*//////////   EMAIL:   [email protected]   //////////*/
(
	try(destroydialog ::mapDrop) catch()
	rollout mapDrop "Easy Image Importer"
	(
		local mapExt = #(".hdr", ".exr", ".jpg", ".tga", ".tif", ".bmp", ".png", ".jpeg", ".psd"), dropState = off		
		local stdProps = #("diffuseMap")
		local classArr = #(Standardmaterial)
		dotnetcontrol drop "Label" pos:[5,5] width:150 height:40
		dotnetcontrol props "CheckedListBox" pos:[5,50] width:140 height:10
		radioButtons 'window_' "Window" pos:[10,60] width:78 height:30 labels:#("Top","Front") columns:2 align:#left
 
		mapped fn trimArr arr &new = (append new (substring arr 8 100))			
 
		fn checkIsImage arg arr =
		(
			arg.Data.ContainsFileDropList() and (arg.Data.GetFileDropList()).count == 1 and \
			(for ext in arr where matchpattern ext pattern:(getFilenameType (arg.Data.GetFileDropList()).item[0]) collect ext).count != 0
		)
		fn updateMat propctrl mtl map idx =
		(
			for ci in 0 to propctrl.CheckedItems.count-1 do
			(
				slotName = if idx == 2 then ("texmap_"+propctrl.CheckedItems.item[ci]) else propctrl.CheckedItems.item[ci]
				setProperty mtl slotName map
			)
		)
 
 
		on mapDrop open do
		(
			props.BackColor = drop.BackColor = (dotNetClass "System.Drawing.Color").FromArgb 40 40 40
			props.ForeColor = drop.ForeColor = (dotNetClass "System.Drawing.Color").FromArgb 200 200 200
			props.BorderStyle = drop.BorderStyle = (dotNetClass "BorderStyle").FixedSingle
			drop.Font = (dotNetObject "System.Drawing.Font" "Impact" 20)
			drop.TextAlign = drop.TextAlign.MiddleCenter
			props.HorizontalScrollbar = props.MultiColumn = false
			drop.Text = "Drop Image " ; drop.AllowDrop = props.CheckOnClick = true
			props.Items.AddRange stdProps
			--format "itm = %\n" mtltype.selection 
		)
 
		on drop DragOver s arg do
		( 
			arg.Effect = if checkIsImage arg mapExt then
			( 
				s.Text = "Done" ; dropState = on ; arg.Effect.Move
			) 
			else 
			(
				s.Text = "NO" ; dropState = off ; arg.Effect.None
			)
		)
 
		on drop DragDrop arg do
		(
		imgFile = (arg.Data.GetFileDropList()).item[0]
		tempMap = openBitMap imgFile
		imgPlane = plane name:(uniqueName("hhh" + (getfilenameFile imgFile))) length:(tempMap.height) width:(tempMap.width) lengthsegs:1 widthsegs:1 mapCoords:true isselected:true
 
------Import an image	START		
		case window_.state of
		(
			------Top
			1:(	imgPlane.transform = matrix3 1)
			-----Front 
			2:(imgPlane.transform = RotateXMatrix 90 )
		)	
 
		imgMaterial = standard()
		imgMaterial.name = imgPlane.name
		imgTexture = bitmaptexture()
		imgTexture.bitmap = tempMap
		imgMaterial.diffuseMap = imgTexture
		imgPlane.material = imgMaterial
		imgMaterial.twoSided = on
		showTextureMap imgMaterial imgMaterial.diffuseMap on
		close tempMap			
		)
	)
 
 
	createdialog mapDrop 160 100 style:#(#style_titlebar, #style_sysmenu, #style_toolwindow)
)